Tabbed Block at Selection-screen

---------------------------------------------------------------------------------------------------------------------------------------
Step1. Here is the short prog code:

SELECTION-SCREEN: BEGIN OF SCREEN 001 AS SUBSCREEN,
                                BEGIN OF BLOCK b1.
PARAMETERS : p_carr TYPE scarr-carrid.
SELECTION-SCREEN: END OF BLOCK b1,
                                END OF SCREEN 001.

SELECTION-SCREEN: BEGIN OF SCREEN 002 AS SUBSCREEN,
                                BEGIN OF BLOCK b2.
PARAMETERS : p_carrd TYPE spfli-carrid,
                       p_connd TYPE spfli-connid.
SELECTION-SCREEN: END OF BLOCK b2,
                                END OF SCREEN 002.

SELECTION-SCREEN: BEGIN OF SCREEN 003 AS SUBSCREEN,
                                BEGIN OF BLOCK b3.
PARAMETERS : p_carrid TYPE sflight-carrid,
                       p_connid TYPE sflight-connid,
                       p_fdate TYPE  sflight-fldate.
SELECTION-SCREEN: END OF BLOCK b3,
                                END OF SCREEN 003.


SELECTION-SCREEN : BEGIN OF TABBED BLOCK tb1 FOR 10 LINES,
                                 TAB (15) tab11 USER-COMMAND code11 DEFAULT SCREEN 001,
                                 TAB (15) tab12 USER-COMMAND code12 DEFAULT SCREEN 002,
                                 TAB (15) tab13 USER-COMMAND code13 DEFAULT SCREEN 003,
                                 END OF BLOCK tb1.

SELECTION-SCREEN : BEGIN OF TABBED BLOCK tb2 FOR 10 LINES,
                                   TAB (15) tab21 USER-COMMAND code21 ,
                                   TAB (15) tab22 USER-COMMAND code22 ,
                                   TAB (15) tab23 USER-COMMAND code23 ,
                                  END OF BLOCK tb2.

INITIALIZATION.
  tab11 = tab21 = 'Scarr Input'.
  tab12 = tab22 = 'Spfli Input'.
  tab13 = tab23 = 'Sflight Input'.
*** For Second Tabbed Block
  tb2-prog = sy-repid.
  tb2-dynnr = '001'.
  tb2-activetab = 'CODE21'.

AT SELECTION-SCREEN.
  CASE sy-ucomm.
    WHEN 'CODE21'.
      tb2-dynnr = '001'.
    WHEN 'CODE22'.
      tb2-dynnr = '002'.
    WHEN 'CODE23'.
      tb2-dynnr = '003'.
    WHEN OTHERS.
  ENDCASE.
-----------------------------------------------------------------------------------------------------------------------------------
Step2. Execute the program and here we have the selection screen output.

---------------------------------------------------------------------------------------------------------------------------------------